Steward

分享是一種喜悅、更是一種幸福

程式語言 - Wine - Assembly (ARM 32) - Single Document Interface (SDI) - Handle Event

---

參考資訊：
http://www.winprog.org/tutorial/
http://winapi.freetechsecrets.com/win32/
https://github.com/gammasoft71/Examples_Win32
http://masm32.com/board/index.php?topic=3584.0
https://learn.microsoft.com/en-us/windows/win32/winmsg/window-styles

當視窗有事件需要被處理時，系統會透過呼叫註冊的Callback副程式來處理，而這個Callback副程式就是在註冊Class時，設定給lpfnWndProc的事件處理副程式，因此，當這個事件處理副程式被呼叫時，可以處理自己感興趣的事件，而其餘事件則交給系統處理(透過呼叫DefWindowProc())，需要注意的是，例如：WM_CLOSE，就必須由該視窗自己處理，因為系統無法知道還有哪些額外的資源需要被釋放掉

main.S

    .global WinMain

    .equiv WC_DIALOG, 0x8002
    .equiv WM_DESTROY, 2
    .equiv WM_CLOSE, 0x10
    .equiv WS_OVERLAPPED, 0
    .equiv WS_CAPTION, 0xc00000
    .equiv WS_SYSMENU, 0x80000
    .equiv WS_THICKFRAME, 0x40000
    .equiv WS_MINIMIZEBOX, 0x20000
    .equiv WS_MAXIMIZEBOX, 0x10000
    .equiv WS_VISIBLE, 0x10000000
    .equiv WS_EX_LEFT, 0x00000000
    .equiv WS_OVERLAPPEDWINDOW, (WS_OVERLAPPED | WS_CAPTION | WS_SYSMENU | WS_THICKFRAME | WS_MINIMIZEBOX | WS_MAXIMIZEBOX)

    .equiv WNDCLASS.style, 0
    .equiv WNDCLASS.lpfnWndProc, 4
    .equiv WNDCLASS.cbClsExtra, 8
    .equiv WNDCLASS.cbWndExtra, 12
    .equiv WNDCLASS.hInstance, 16
    .equiv WNDCLASS.hIcon, 20
    .equiv WNDCLASS.hCursor, 24
    .equiv WNDCLASS.hbrBackground, 28
    .equiv WNDCLASS.lpszMenuName, 32
    .equiv WNDCLASS.lpszClassName, 36

    .data
hWin: .skip 4
szMsg: .skip 28
szAppName: .asciz "main"
pDefWndProc: .skip 4
wndClass:
    .space 4   @ style
    .space 4   @ lpfnWndProc
    .space 4   @ cbClsExtra
    .space 4   @ cbWndExtra
    .space 4   @ hInstance
    .space 4   @ hIcon
    .space 4   @ hCursor
    .space 4   @ hbrBackground
    .space 4   @ lpszMenuName
    .space 4   @ lpszClassName
wndClass_end:
WNDCLASS_SIZE: .word wndClass_end - wndClass

    .text
WndProc:
    push { lr }
    cmp r1, #WM_CLOSE
    beq handle_close
    cmp r1, #WM_DESTROY
    beq handle_destroy
    b handle_default
  
handle_close:
    bl DestroyWindow
    eor r0, r0
    b finish
  
handle_destroy:
    ldr r0, =0
    bl PostQuitMessage
    eor r0, r0
    b finish
  
handle_default:
    bl DefWindowProcA
    b finish
  
finish:
    pop { pc }
 
WinMain:
    push { lr }
 
    ldr r0, =wndClass
    ldr r1, =WndProc
    str r1, [r0, #WNDCLASS.lpfnWndProc]
    ldr r1, =szAppName
    str r1, [r0, #WNDCLASS.lpszClassName]
    bl RegisterClassA
 
    ldr r3, =0
    ldr r2, =0
    ldr r1, =0
    ldr r0, =0
    push { r0, r1, r2, r3 }
    ldr r3, =300
    ldr r2, =300
    ldr r1, =0
    ldr r0, =0
    push { r0, r1, r2, r3 }
    ldr r3, =WS_OVERLAPPEDWINDOW | WS_VISIBLE
    ldr r2, =szAppName
    ldr r1, =szAppName
    ldr r0, =WS_EX_LEFT
    bl CreateWindowExA
    add sp, sp, #32
    ldr r1, =hWin
    str r0, [r1]
 
loop:
    ldr r3, =0
    ldr r2, =0
    ldr r1, =0
    ldr r0, =szMsg
    bl GetMessageA
 
    cmp r0, #0
    beq exit
   
    ldr r0, =szMsg
    bl DispatchMessageA
    b loop
 
exit:
    pop { pc }

編譯、執行

$ winegcc-armhf -b arm-linux-gnueabihf main.S -o main.exe
$ WINEPREFIX=~/.wine_arm32 myarm32 main.exe.so