Netwide Assembler (NASM) >> Assembly (x86) >> Win32 API (NASMX)

Mouse Event

---

參考資訊：
1. nasm
2. masm32

WM_MOUSEMOVE

fwKeys = wParam;       // key flags
xPos = LOWORD(lParam); // horizontal position of cursor
yPos = HIWORD(lParam); // vertical position of cursor

main.asm

    %include "c:\\nasmx\\inc\\nasmx.inc"
    %include "c:\\nasmx\\inc\\win32\\msvcrt.inc"
    %include "c:\\nasmx\\inc\\win32\\windows.inc"
    %include "c:\\nasmx\\inc\\win32\\user32.inc"
    %include "c:\\nasmx\\inc\\win32\\kernel32.inc"
 
    entry start
 
    section .data
hWin         dd 0
hInstance    dd 0
defWndProc   dd 0
CommandLine  dd 0
buf          times 255 db 0
fmt          db "%d-%d",0
szCaption    declare(NASMX_TCHAR) NASMX_TEXT("main"),0
  
NASMX_ISTRUC msg, MSG
    NASMX_AT hwnd,    NULL
    NASMX_AT message, NULL
    NASMX_AT wParam,  NULL
    NASMX_AT lParam,  NULL
    NASMX_AT time,    NULL
    NASMX_ISTRUC pt, POINT
        NASMX_AT x, 0
        NASMX_AT y, 0
    NASMX_IENDSTRUC
NASMX_IENDSTRUC
  
    section .text
proc WndProc, dword hWnd, uint_t uMsg, dword wParam, dword lParam
    locals
        local x, dword
        local y, dword
    endlocals
  
    switch dword [argv(.uMsg)]
    case dword WM_MOUSEMOVE
        mov eax, [argv(.lParam)]
        and eax, 0ffffh
        mov [var(.x)], eax
        
        mov eax, [argv(.lParam)]
        shr eax, 16
        and eax, 0ffffh
        mov [var(.y)], eax
        invoke sprintf, buf, fmt, [var(.x)], [var(.y)]
        invoke SetWindowText, [argv(.hWnd)], buf
        break
    case dword WM_CLOSE
        invoke DestroyWindow, [argv(.hWnd)]
        break
    case dword WM_DESTROY
        invoke PostQuitMessage, 0
        break
    default
        invoke CallWindowProc, [defWndProc], [argv(.hWnd)], [argv(.uMsg)], [argv(.wParam)], [argv(.lParam)]
    endswitch
endproc
  
proc WinMain, dword hInst, dword hPrevInst, dword CmdLine, dword CmdShow
    locals none
   
    invoke CreateWindowEx, WS_EX_LEFT, WC_DIALOG, szCaption, \
        WS_OVERLAPPEDWINDOW | WS_VISIBLE, 0, 0, 300, 300, NULL, NULL, NULL, NULL
    mov [hWin], eax
  
    invoke SetWindowLong, [hWin], GWL_WNDPROC, WndProc
    mov [defWndProc], eax
  
    do
        invoke DispatchMessage, msg
        invoke GetMessage, msg, NULL, NULL, NULL
    while eax, !=, 0
   
    mov eax, dword [msg + MSG.wParam]
endproc
   
proc start, dword argc, dword argv
    locals none
   
    invoke GetModuleHandle, NULL
    mov [hInstance], eax
   
    invoke GetCommandLine, NULL
    mov [CommandLine], eax
   
    invoke WinMain, [hInstance], NULL, [CommandLine], SW_SHOWNORMAL
    invoke ExitProcess, NULL
endproc

Line 38~49：將滑鼠座標顯示在視窗標題

Makefile

export WINEPREFIX=/home/user/.wine_amd64

TARGET=main
MYWINE=box86 wine
NASM32=/home/user/.wine_amd64/drive_c/nasmx

all:
	${MYWINE} ${NASM32}/bin/nasm.exe -fwin32 ${TARGET}.asm
	${MYWINE} ${NASM32}/bin/GoLink.exe /entry _main ${TARGET}.obj kernel32.dll user32.dll msvcrt.dll /mix

run:
	${MYWINE} ${TARGET}.exe

clean:
	rm -rf ${TARGET}.exe ${TARGET}.obj

編譯、執行

$ make
$ make run

返回上一頁