Netwide Assembler (NASM) >> Assembly (x86) >> Win32 API (NASMX) >> Painting

Draw Line

---

參考資訊：
1. nasm
2. masm32

線的起始點位置是位於(x=0, y=0)，使用者可以呼叫MoveToEx()設定新的起始點，而使用LineTo()就可以畫出一條直線，新的起始點則是線的結束位置

main.asm

    %include "c:\\nasmx\\inc\\nasmx.inc"
    %include "c:\\nasmx\\inc\\win32\\msvcrt.inc"
    %include "c:\\nasmx\\inc\\win32\\windows.inc"
    %include "c:\\nasmx\\inc\\win32\\gdi32.inc"
    %include "c:\\nasmx\\inc\\win32\\user32.inc"
    %include "c:\\nasmx\\inc\\win32\\kernel32.inc"
       
    entry start
       
    section .data
hWin         dd 0
hInstance    dd 0
defWndProc   dd 0
CommandLine  dd 0
szCaption    declare(NASMX_TCHAR) NASMX_TEXT("main"),0
        
NASMX_ISTRUC msg, MSG
NASMX_IENDSTRUC
   
NASMX_ISTRUC ps, PAINTSTRUCT
NASMX_IENDSTRUC
        
    section .text
proc WndProc, dword hWnd, uint_t uMsg, dword wParam, dword lParam
    locals
        local hdc, DWORD
        local r_pen, DWORD
        local g_pen, DWORD
        local b_pen, DWORD
    endlocals
     
    switch dword [argv(.uMsg)]
    case dword WM_PAINT
        invoke BeginPaint, [argv(.hWnd)], ps
        mov [var(.hdc)], eax
   
        invoke CreatePen, PS_SOLID, 3, 0ffh
        mov [var(.r_pen)], eax
        invoke CreatePen, PS_SOLID, 3, 0ff00h
        mov [var(.g_pen)], eax
        invoke CreatePen, PS_SOLID, 3, 0ff0000h
        mov [var(.b_pen)], eax
 
        invoke SelectObject, [var(.hdc)], [var(.r_pen)]
        invoke MoveToEx, [var(.hdc)], 10, 100, NULL
        invoke LineTo, [var(.hdc)], 250, 100
  
        invoke SelectObject, [var(.hdc)], [var(.g_pen)]
        invoke MoveToEx, [var(.hdc)], 10, 150, NULL
        invoke LineTo, [var(.hdc)], 250, 150
  
        invoke SelectObject, [var(.hdc)], [var(.b_pen)]
        invoke MoveToEx, [var(.hdc)], 10, 200, NULL
        invoke LineTo, [var(.hdc)], 250, 200
  
        invoke EndPaint, [argv(.hWnd)], ps
        invoke DeleteObject, [var(.r_pen)]
        invoke DeleteObject, [var(.g_pen)]
        invoke DeleteObject, [var(.b_pen)]
        break
    case dword WM_CLOSE
        invoke DestroyWindow, [argv(.hWnd)]
        break
    case dword WM_DESTROY
        invoke PostQuitMessage, 0
        break
    default
        invoke CallWindowProc, [defWndProc], [argv(.hWnd)], [argv(.uMsg)], [argv(.wParam)], [argv(.lParam)]
    endswitch
endproc
        
proc WinMain, dword hInst, dword hPrevInst, dword CmdLine, dword CmdShow
    locals none
         
    invoke CreateWindowEx, WS_EX_LEFT, WC_DIALOG, szCaption, \
        WS_OVERLAPPEDWINDOW | WS_VISIBLE, 0, 0, 300, 300, NULL, NULL, NULL, NULL
    mov [hWin], eax
        
    invoke SetWindowLong, [hWin], GWL_WNDPROC, WndProc
    mov [defWndProc], eax
    
    do
        invoke DispatchMessage, msg
        invoke GetMessage, msg, NULL, NULL, NULL
    while eax, !=, 0
         
    mov eax, dword [msg + MSG.wParam]
endproc
         
proc start, dword argc, dword argv
    locals none
         
    invoke GetModuleHandle, NULL
    mov [hInstance], eax
         
    invoke GetCommandLine, NULL
    mov [CommandLine], eax
         
    invoke WinMain, [hInstance], NULL, [CommandLine], SW_SHOWNORMAL
    invoke ExitProcess, NULL
endproc

Line 37~54：產生三隻Pen並且畫出三條直線，需要注意的是，同一時間只能選擇一隻Pen

Makefile

export WINEPREFIX=/home/user/.wine_amd64

TARGET=main
MYWINE=box86 wine
NASM32=/home/user/.wine_amd64/drive_c/nasmx

all:
	${MYWINE} ${NASM32}/bin/nasm.exe -fwin32 ${TARGET}.asm
	${MYWINE} ${NASM32}/bin/GoLink.exe /entry _main ${TARGET}.obj kernel32.dll user32.dll gdi32.dll msvcrt.dll /mix

run:
	${MYWINE} ${TARGET}.exe

clean:
	rm -rf ${TARGET}.exe ${TARGET}.obj

編譯、執行

$ make
$ make run

返回上一頁