程式語言 - High Level Assembly (HLA) - Win32 API (HLA v1.x) - Mouse Event

參考網站：
http://winapi.freetechsecrets.com/win32/
http://masm32.com/board/index.php?topic=3584.0
https://www.plantation-productions.com/Webster/
https://www.plantation-productions.com/Webster/Win32Asm/win32API.html

WM_MOUSEMOVE

fwKeys = wParam;       // key flags
xPos = LOWORD(lParam); // horizontal position of cursor
yPos = HIWORD(lParam); // vertical position of cursor

main.hla

program main;
   
#include("w.hhf")
#include("args.hhf")
#include("memory.hhf")
#include("strings.hhf")
   
static
    buf:         byte[255];
    hWin:        dword;
    hInstance:   dword;
    CommandLine: string;
    defWndProc:  dword;
 
    wsprintf: procedure(p0:dword; p1:dword; p2:dword; p3:dword); @stdcall; external("__imp__wsprintfA");
 
readonly
    fmt:       string:= "%d-%d";
    szCaption: string:= "main";
  
procedure WndProc(hWnd:dword; uMsg:uns32; wParam:dword; lParam:dword); @stdcall;
var
    x: dword;
    y: dword;
endvar;

begin WndProc;
    if (uMsg == w.WM_MOUSEMOVE) then
        mov(lParam, eax);
        and($0ffff, eax);
        mov(eax, x);

        mov(lParam, eax);
        shr(16, eax);
        and($0ffff, eax);
        mov(eax, y);
        wsprintf(&buf, fmt, x, y);
        w.SetWindowText(hWnd, &buf);
        xor(eax, eax);
    elseif (uMsg == w.WM_CLOSE) then
        w.DestroyWindow(hWnd);
        xor(eax, eax);
    elseif (uMsg == w.WM_DESTROY) then
        w.PostQuitMessage(0);
        xor(eax, eax);
    else
        w.CallWindowProc(defWndProc, hWnd, uMsg, wParam, lParam);
    endif;
end WndProc;
  
procedure WinMain(hInst:dword; hPrevInst:dword; CmdLine:string; CmdShow:dword);
var
    msg: w.MSG;
   
begin WinMain;
    w.CreateWindowEx(w.WS_EX_LEFT, w.WC_DIALOG, szCaption,
        w.WS_OVERLAPPEDWINDOW | w.WS_VISIBLE, 0, 0, 300, 300, 0, 0, NULL, NULL);
    mov(eax, hWin);
  
    w.SetWindowLong(hWin, w.GWL_WNDPROC, &WndProc);
    mov(eax, defWndProc);
       
    forever
        w.GetMessage(msg, NULL, 0, 0);
        breakif(!eax);
   
        w.DispatchMessage(msg);
    endfor;
    mov(msg.wParam, eax);
end WinMain;
   
begin main;
    w.GetModuleHandle(NULL);
    mov(eax, hInstance);
    mov(arg.cmdLn(), CommandLine);
  
    WinMain(hInstance, NULL, CommandLine, w.SW_SHOWNORMAL);
  
    w.ExitProcess(eax);
end main;

Line 28~39：將滑鼠座標顯示在視窗標題

完成