Windows NT Driver >> Assembly

Queue IRP


參考資訊:
1. Four-F
2. Source Code

驅動程式作為User Application跟硬體的溝通橋樑,最常遇到的問題就是硬體處理速度不夠快,導致驅動程式需要等待硬體完成後,再繼續處理下一筆資料,但是驅動程式如果要跟User Application溝通這些同步事情,會產生額外的等待時間,因此,為了達到比較好的處理效能,一般驅動程式做會Queue Irp的動作,讓處理的間隔可以縮到最小,這也是這篇教學要說明的東西,教導使用者一些Queue Irp的基本觀念和作法。

首先要知道的就是,儲存Irp的地方在哪?在Windows驅動程式裡,可以使用List作為儲存媒介(使用者也可以使用其它方式儲存),使用步驟相當簡單,如下所示:
1. InitializeListHead()
2. InsertHeadList()
3. IsListEmpty()
4. RemoveHeadList()
首先初始化List(InitializeListHead()),接著插入(InsertHeadList())需要儲存的資料,接著判斷List是否還有資料(IsListEmpty()),假如還有資料,則取出(RemoveHeadList())處裡

Irp是處裡資料的最小單位,一個Irp通常代表處理一筆資料的訊息,因此,當硬體來不及處理資料時,驅動程式需要做Pending Irp的動作,讓User Application知道這筆資料稍後處理,Pending Irp的步驟如下:
1. IoMarkIrpPending()
2. IoCompleteRequest(STATUS_PENDING)
回傳Pending,告知I/O Manager,這筆Irp資料先Pending一下,稍後處理

接著就是User Application如何知道資料是否處理完畢或者被Pending了呢?在CreateFile()時,如果沒有用FILE_FLAG_OVERLAPPED,則代表每一筆資料都是必須完成才會回傳,此種寫法也稱為Blocking方式,如:呼叫WriteFile()後,必須等待驅動程式完成該Irp才會繼續往下,否則呼叫WriteFile()後,會卡在這個Win32 API,相反地,如果CreateFile()使用FILE_FLAG_OVERLAPPED,而呼叫WriteFile()時,驅動程式回傳Pending,則WriteFile()會馬上回傳ERROR_IO_PENDING,告知User Application,該筆資料驅動程式會稍後處裡,此種寫法也稱為Non-Blocking方式,那如何得知該筆資料處理完畢了呢?當使用Non-Blocking寫法,會在WriteFile()傳入一個OVERLAPPED參數,該參數裡面有一個Event,用來告知是否已經處理完畢了。

Queue IRP流程:
1. InsertHeadList()
2. IoMarkIrpPending()
3. IoCompleteRequest(STATUS_PENDING)
4. IsListEmpty()
5. RemoveHeadList()
6. IoCompleteRequest(STATUS_SUCCESS)

main.asm

.386p
.model flat, stdcall
option casemap:none
 
include c:\masm32\include\w2k\ntstatus.inc
include c:\masm32\include\w2k\ntddk.inc
include c:\masm32\include\w2k\ntoskrnl.inc
include c:\masm32\include\w2k\ntddkbd.inc
include c:\masm32\Macros\Strings.mac
includelib c:\masm32\lib\wxp\i386\ntoskrnl.lib

public DriverEntry

OurDeviceExtension struct
  pNextDev  PDEVICE_OBJECT ?
  stQueue   LIST_ENTRY     <>
  stDPC     KDPC           <>
  stTime    KTIMER         <>
OurDeviceExtension ends

IOCTL_QUEUE   equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_ANY_ACCESS)
IOCTL_PROCESS equ CTL_CODE(FILE_DEVICE_UNKNOWN, 801h, METHOD_BUFFERED, FILE_ANY_ACCESS)

.const
DEV_NAME    word "\","D","e","v","i","c","e","\","M","y","D","r","i","v","e","r",0
SYM_NAME    word "\","D","o","s","D","e","v","i","c","e","s","\","M","y","D","r","i","v","e","r",0
MSG_QUEUE   byte "IOCTL_QUEUE",0
MSG_PROCESS byte "IOCTL_PROCESS",0

.code
OnTimer proc pDpc:PKDPC, pContext:PVOID, pArg1:PVOID, PArg2:PVOID
  mov eax, pContext
  mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
  lea eax, (OurDeviceExtension PTR [eax]).stQueue
  IsListEmpty eax
  .if eax == TRUE
    mov eax, pContext
    mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
    invoke KeCancelTimer, addr (OurDeviceExtension PTR [eax]).stTime
    invoke DbgPrint, $CTA0("Finish")
  .else
    mov eax, pContext
    mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
    lea eax, (OurDeviceExtension PTR [eax]).stQueue
    RemoveHeadList eax
    
    ; CONTAINING_RECORD 
    sub eax, _IRP.Tail.Overlay.ListEntry
    mov (_IRP PTR [eax]).IoStatus.Status, STATUS_SUCCESS
    push 0
    pop (_IRP PTR [eax]).IoStatus.Information
    fastcall IofCompleteRequest, eax, IO_NO_INCREMENT
    invoke DbgPrint, $CTA0("Complete Irp")
  .endif
  ret
OnTimer endp

IrpOpenClose proc pDevObj:PDEVICE_OBJECT, pIrp:PIRP
  IoGetCurrentIrpStackLocation pIrp
  movzx eax, (IO_STACK_LOCATION PTR [eax]).MajorFunction
  .if eax == IRP_MJ_CREATE
    invoke DbgPrint, $CTA0("IRP_MJ_CREATE")
  .elseif eax == IRP_MJ_CLOSE
    invoke DbgPrint, $CTA0("IRP_MJ_CLOSE")
  .endif

  mov eax, pIrp
  and (_IRP PTR [eax]).IoStatus.Information, 0
  mov (_IRP PTR [eax]).IoStatus.Status, STATUS_SUCCESS
  fastcall IofCompleteRequest, pIrp, IO_NO_INCREMENT
  mov eax, STATUS_SUCCESS
  ret
IrpOpenClose endp

IrpIOCTL proc uses ebx ecx pOurDevice:PDEVICE_OBJECT, pIrp:PIRP
  local pdx:PTR Dev_Ext
  local stTimePeriod:LARGE_INTEGER

  mov eax, pOurDevice
  push (DEVICE_OBJECT PTR [eax]).DeviceExtension
  pop pdx

  IoGetCurrentIrpStackLocation pIrp
  mov eax, (IO_STACK_LOCATION PTR [eax]).Parameters.DeviceIoControl.IoControlCode
  .if eax == IOCTL_QUEUE
    invoke DbgPrint, offset MSG_QUEUE

    mov ebx, pdx
    lea ebx, (OurDeviceExtension PTR [ebx]).stQueue
    mov ecx, pIrp
    lea ecx, (_IRP PTR [ecx]).Tail.Overlay.ListEntry
    InsertHeadList ebx, ecx
    IoMarkIrpPending pIrp
    mov eax, STATUS_PENDING
    ret
  .elseif eax == IOCTL_PROCESS
    invoke DbgPrint, offset MSG_PROCESS
    
    or stTimePeriod.HighPart, -1
    mov stTimePeriod.LowPart, -10000000
    mov ebx, pdx
    invoke KeSetTimerEx, addr (OurDeviceExtension PTR [ebx]).stTime, stTimePeriod.LowPart, stTimePeriod.HighPart, 10, addr (OurDeviceExtension PTR [ebx]).stDPC
  .endif

  mov eax, pIrp
  mov (_IRP PTR [eax]).IoStatus.Status, STATUS_SUCCESS
  and (_IRP PTR [eax]).IoStatus.Information, 0
  fastcall IofCompleteRequest, pIrp, IO_NO_INCREMENT
  mov eax, STATUS_SUCCESS
  ret
IrpIOCTL endp

Unload proc pOurDriver:PDRIVER_OBJECT
  local szSymName:UNICODE_STRING
         
  invoke RtlInitUnicodeString, addr szSymName, offset SYM_NAME
  invoke IoDeleteSymbolicLink, addr szSymName
         
  mov eax, pOurDriver
  invoke IoDeleteDevice, (DRIVER_OBJECT PTR [eax]).DeviceObject
  ret
Unload endp
  
DriverEntry proc pOurDriver:PDRIVER_OBJECT, pOurRegistry:PUNICODE_STRING
  local pOurDevice:PDEVICE_OBJECT
  local suDevName:UNICODE_STRING
  local szSymName:UNICODE_STRING
    
  mov eax, pOurDriver
  mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_CREATE * (sizeof PVOID)], offset IrpOpenClose
  mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_CLOSE  * (sizeof PVOID)], offset IrpOpenClose
  mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_DEVICE_CONTROL * (sizeof PVOID)], offset IrpIOCTL
  mov (DRIVER_OBJECT PTR [eax]).DriverUnload, offset Unload
    
  invoke RtlInitUnicodeString, addr suDevName, offset DEV_NAME
  invoke RtlInitUnicodeString, addr szSymName, offset SYM_NAME
  invoke IoCreateDevice, pOurDriver, sizeof OurDeviceExtension, addr suDevName, FILE_DEVICE_UNKNOWN, 0, FALSE, addr pOurDevice
  .if eax == STATUS_SUCCESS
    mov eax, pOurDevice
    or (DEVICE_OBJECT PTR [eax]).Flags, DO_BUFFERED_IO
    and (DEVICE_OBJECT PTR [eax]).Flags, not DO_DEVICE_INITIALIZING
    
    mov eax, pOurDevice
    mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
    lea eax, (OurDeviceExtension PTR [eax]).stQueue
    InitializeListHead eax

    mov eax, pOurDevice
    mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
    invoke KeInitializeTimer, addr (OurDeviceExtension ptr [eax]).stTime

    mov eax, pOurDevice
    mov eax, (DEVICE_OBJECT PTR [eax]).DeviceExtension
    invoke KeInitializeDpc, addr (OurDeviceExtension ptr [eax]).stDPC, offset OnTimer, pOurDevice
    invoke IoCreateSymbolicLink, addr szSymName, addr suDevName
  .endif
  ret
DriverEntry endp
end DriverEntry
.end

DriverEntry()初始List以及DPC Timer,DPC Timer用來定期確認List是否還有資料需要處理,當然,使用Thread檢查或許更恰當些
IrpIOCTL()IOCTL_QUEUE代表該IOCTL會被Queue起來,稍後處理,而當收到IOCTL_PROCESS時,則啟動DPC Timer開始處理那些被Queue起來的Irp
OnTimer()處理Queue裡面的Irp

app.asm

.386p
.model flat, stdcall
option casemap:none
 
include c:\masm32\include\windows.inc
include c:\masm32\include\masm32.inc
include c:\masm32\include\user32.inc
include c:\masm32\include\msvcrt.inc
include c:\masm32\include\kernel32.inc
include c:\masm32\include\w2k\ntddkbd.inc
include c:\masm32\Macros\Strings.mac
  
includelib c:\masm32\lib\user32.lib
includelib c:\masm32\lib\masm32.lib
includelib c:\masm32\lib\msvcrt.lib
includelib c:\masm32\lib\kernel32.lib
 
IOCTL_QUEUE   equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_ANY_ACCESS)
IOCTL_PROCESS equ CTL_CODE(FILE_DEVICE_UNKNOWN, 801h, METHOD_BUFFERED, FILE_ANY_ACCESS)
 
.const
DEV_NAME db "\\.\MyDriver",0
 
.data?
cnt   dd ?
hFile dd ?
dwRet dd ?
event dd 3 dup(?)
ov    OVERLAPPED <?>

.code
start:
  invoke CreateFile, offset DEV_NAME, GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ, 0, OPEN_EXISTING, FILE_FLAG_OVERLAPPED or FILE_ATTRIBUTE_NORMAL, 0
  .if eax == INVALID_HANDLE_VALUE
    invoke crt_printf, $CTA0("failed to open mydriver\n")
    invoke ExitProcess, -1
  .endif
  mov hFile, eax
  invoke crt_memset, offset ov, 0, sizeof OVERLAPPED
  
  mov cnt, 3
  .while cnt > 0
    invoke CreateEvent, NULL, TRUE, FALSE, NULL
    push eax
    pop ov.hEvent
    
    mov ecx, cnt
    mov edi, offset event
    mov [edi + ecx * 4], eax
    
    invoke crt_printf, $CTA0("queue event\n")
    invoke DeviceIoControl, hFile, IOCTL_QUEUE, NULL, 0, NULL, 0, offset dwRet, offset ov
    sub cnt, 1
  .endw
  
  invoke crt_printf, $CTA0("process all of events\n")
  invoke DeviceIoControl, hFile, IOCTL_PROCESS, NULL, 0, NULL, 0, offset dwRet, NULL
  
  mov cnt, 3
  .while cnt > 0
    mov ecx, cnt
    mov edi, offset event
    mov eax, [edi + ecx * 4]
    
    push eax
    pop ov.hEvent
    
    invoke WaitForSingleObject, ov.hEvent, INFINITE 
    invoke CloseHandle, ov.hEvent
    invoke crt_printf, $CTA0("wait complete\n")
    sub cnt, 1
  .endw
  invoke CloseHandle, hFile
  invoke ExitProcess, 0
end start

結果


返回上一頁