Windows NT Driver >> Assembly >> File
DO_NEITHER_IO
參考資訊：
1. Four-F
2. Source Code
基本上，Microsoft沒有定義DO_NEITHER_IO這個Flag，而Neither I/O的意思就是Neither Buffered Nor Direct I/O，因此，當沒有設定DO_BUFFERED_IO或DO_DIRECT_IO Flag時，就會使用Neither的方式，使用這種方式時，I/O Manager會將User Buffer的指標，透過操作後，傳遞給驅動程式使用，因此，驅動程式可以直接存取User Buffer的資料，所以存取速度可以得到很大的改善，對於有速度要求的驅動程式來說，建議使用Neither的方式，不過，關於User Buffer指標的存取問題上，會遇到更多需要面對的問題，如：指標的有效性以及多次存取的同步問題，因此，在選擇使用上，更需要考量到這些額外付出的代價是否值得使用，因為，驅動程式以及User Application雙方都需要很嚴謹的看待這塊共用的Buffer。
Microsoft的說明網頁：
using-neither-buffered-nor-direct-i-o
記憶體指標：
| IRP | Buffer | Length |
|---|---|---|
| IRP_MJ_READ | (Irp) UserBuffer |
(IrpStack) Parameters.Read.Length |
| IRP_MJ_WRITE | (Irp) UserBuffer |
(IrpStack) Parameters.Write.Length |
main.asm
.386p
.model flat, stdcall
option casemap:none
include c:\masm32\Macros\Strings.mac
include c:\masm32\include\w2k\ntstatus.inc
include c:\masm32\include\w2k\ntddk.inc
include c:\masm32\include\w2k\ntoskrnl.inc
include c:\masm32\include\w2k\ntddkbd.inc
include c:\masm32\include\wxp\wdm.inc
include c:\masm32\include\wxp\seh0.inc
includelib c:\masm32\lib\wxp\i386\ntoskrnl.lib
public DriverEntry
OurDeviceExtension struct
pNextDevice PDEVICE_OBJECT ?
szBuffer byte 255 dup(?)
OurDeviceExtension ends
.const
DEV_NAME word "\","D","e","v","i","c","e","\","M","y","D","r","i","v","e","r",0
SYM_NAME word "\","D","o","s","D","e","v","i","c","e","s","\","M","y","D","r","i","v","e","r",0
.code
IrpOpenClose proc pOurDevice:PDEVICE_OBJECT, pIrp:PIRP
IoGetCurrentIrpStackLocation pIrp
movzx eax, (IO_STACK_LOCATION PTR [eax]).MajorFunction
.if eax == IRP_MJ_CREATE
invoke DbgPrint, $CTA0("IRP_MJ_CREATE")
.elseif eax == IRP_MJ_CLOSE
invoke DbgPrint, $CTA0("IRP_MJ_CLOSE")
.endif
mov eax, pIrp
and (_IRP PTR [eax]).IoStatus.Information, 0
mov (_IRP PTR [eax]).IoStatus.Status, STATUS_SUCCESS
fastcall IofCompleteRequest, pIrp, IO_NO_INCREMENT
mov eax, STATUS_SUCCESS
ret
IrpOpenClose endp
IrpReadWrite proc uses ebx pOurDevice:PDEVICE_OBJECT, pIrp:PIRP
local bReadable:dword
local bWritable:dword
local dwLen:dword
local pBuf:dword
local pdx:PTR OurDeviceExtension
and dwLen, 0
mov eax, pOurDevice
push (DEVICE_OBJECT PTR [eax]).DeviceExtension
pop pdx
IoGetCurrentIrpStackLocation pIrp
movzx eax, (IO_STACK_LOCATION PTR [eax]).MajorFunction
.if eax == IRP_MJ_WRITE
invoke DbgPrint, $CTA0("IRP_MJ_WRITE")
IoGetCurrentIrpStackLocation pIrp
push (IO_STACK_LOCATION PTR [eax]).Parameters.Write._Length
pop dwLen
mov eax, pIrp
push (_IRP PTR [eax]).UserBuffer
pop pBuf
invoke DbgPrint, $CTA0("Address: 0x%x, Length: %d"), pBuf, dwLen
mov bReadable, 0
_try
invoke ProbeForRead, pBuf, dwLen, 1
mov eax, pdx
mov ebx, pBuf
invoke memcpy, addr (OurDeviceExtension PTR [eax]).szBuffer, ebx, dwLen
mov bReadable, 1
_finally
.if bReadable == 0
invoke DbgPrint, $CTA0("Failed to read from user buffer")
.endif
.elseif eax == IRP_MJ_READ
invoke DbgPrint, $CTA0("IRP_MJ_READ")
mov eax, pIrp
push (_IRP PTR [eax]).UserBuffer
pop pBuf
mov bWritable, 0
_try
invoke ProbeForWrite, pBuf, dwLen, 1
mov eax, pOurDevice
push (DEVICE_OBJECT PTR [eax]).DeviceExtension
pop pdx
mov eax, pdx
mov ebx, pBuf
invoke strcpy, ebx, addr (OurDeviceExtension PTR [eax]).szBuffer
mov eax, pdx
invoke strlen, addr (OurDeviceExtension PTR [eax]).szBuffer
inc eax
push eax
pop dwLen
mov bWritable, 1
_finally
.if bWritable == 0
invoke DbgPrint, $CTA0("Failed to write to user buffer")
.endif
.endif
mov eax, pIrp
push dwLen
pop (_IRP PTR [eax]).IoStatus.Information
mov (_IRP PTR [eax]).IoStatus.Status, STATUS_SUCCESS
fastcall IofCompleteRequest, pIrp, IO_NO_INCREMENT
mov eax, STATUS_SUCCESS
ret
IrpReadWrite endp
Unload proc pOurDriver:PDRIVER_OBJECT
local szSymName:UNICODE_STRING
invoke RtlInitUnicodeString, addr szSymName, offset SYM_NAME
invoke IoDeleteSymbolicLink, addr szSymName
mov eax, pOurDriver
invoke IoDeleteDevice, (DRIVER_OBJECT PTR [eax]).DeviceObject
ret
Unload endp
DriverEntry proc pOurDriver:PDRIVER_OBJECT, pOurRegistry:PUNICODE_STRING
local pOurDevice:PDEVICE_OBJECT
local suDevName:UNICODE_STRING
local szSymName:UNICODE_STRING
mov eax, pOurDriver
mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_CREATE * (sizeof PVOID)], offset IrpOpenClose
mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_CLOSE * (sizeof PVOID)], offset IrpOpenClose
mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_WRITE * (sizeof PVOID)], offset IrpReadWrite
mov (DRIVER_OBJECT PTR [eax]).MajorFunction[IRP_MJ_READ * (sizeof PVOID)], offset IrpReadWrite
mov (DRIVER_OBJECT PTR [eax]).DriverUnload, offset Unload
invoke RtlInitUnicodeString, addr suDevName, offset DEV_NAME
invoke RtlInitUnicodeString, addr szSymName, offset SYM_NAME
invoke IoCreateDevice, pOurDriver, sizeof OurDeviceExtension, addr suDevName, FILE_DEVICE_UNKNOWN, 0, FALSE, addr pOurDevice
.if eax == STATUS_SUCCESS
mov eax, pOurDevice
and (DEVICE_OBJECT PTR [eax]).Flags, not DO_DEVICE_INITIALIZING
invoke IoCreateSymbolicLink, addr szSymName, addr suDevName
.endif
ret
DriverEntry endp
end DriverEntry
.end
IrpFile()收到IRP_MJ_WRITE時，Driver複製User Buffer的內容到szBuffer，而收到IRP_MJ_READ時，將szBuffer內容又複製回User Buffer，完成暫存的功能，IoStatus.Information的數值就是ReadFile()或WriteFile()完成的長度。
app.asm
.386p
.model flat, stdcall
option casemap:none
include c:\masm32\include\windows.inc
include c:\masm32\include\masm32.inc
include c:\masm32\include\user32.inc
include c:\masm32\include\msvcrt.inc
include c:\masm32\include\kernel32.inc
includelib c:\masm32\lib\user32.lib
includelib c:\masm32\lib\masm32.lib
includelib c:\masm32\lib\msvcrt.lib
includelib c:\masm32\lib\kernel32.lib
.const
DEV_NAME db "\\.\MyDriver",0
MSG_ERR db "failed to open mydriver",0
MSG_SEND db "I am error",0
MSG_WR db "WR: %s, %d",10,13,0
MSG_RD db "RD: %s, %d",10,13,0
.data?
hFile dd ?
dwRet dd ?
szBuffer db 255 dup(?)
.code
start:
invoke CreateFile, offset DEV_NAME, GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ, 0, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, 0
.if eax == INVALID_HANDLE_VALUE
invoke crt_printf, offset MSG_ERR
invoke ExitProcess, -1
.endif
mov hFile, eax
invoke StrLen, offset MSG_SEND
inc eax
mov dwRet, eax
invoke crt_printf, offset MSG_WR, offset MSG_SEND, dwRet
invoke WriteFile, hFile, offset MSG_SEND, dwRet, offset dwRet, 0
invoke crt_memset, offset szBuffer, 0, 255
invoke ReadFile, hFile, offset szBuffer, 255, offset dwRet, 0
invoke crt_printf, offset MSG_RD, offset szBuffer, dwRet
invoke CloseHandle, hFile
invoke ExitProcess, 0
end start
結果
