Kernel Mode Driver Framework >> Assembly (PNP) >> Timer
WDF
參考資訊：
1. Source Code
2. using-timers
WDF重新封裝出一個新的Timer計時器，基本上，用法跟DPC Timer相似，可以設定成週期性或單一次觸發類型，使用步驟如下：
1. WdfTimerCreate()
2. WdfTimerStart()
3. WdfTimerStop()
main.asm
.386p
.model flat, stdcall
option casemap:none
include c:\masm32\Macros\Strings.mac
include c:\masm32\include\w2k\ntdef.inc
include c:\masm32\include\w2k\ntstatus.inc
include c:\masm32\include\w2k\ntddk.inc
include c:\masm32\include\w2k\ntoskrnl.inc
include c:\masm32\include\w2k\ntddkbd.inc
include c:\masm32\include\wxp\wdm.inc
include c:\masm32\include\wdf\umdf\1.9\wudfddi_types.inc
include c:\masm32\include\wdf\kmdf\1.9\wdf.inc
include c:\masm32\include\wdf\kmdf\1.9\wdftypes.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfglobals.inc
include c:\masm32\include\wdf\kmdf\1.9\wdffuncenum.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfobject.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfdevice.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfdriver.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfrequest.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfio.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfcore.inc
include c:\masm32\include\wdf\kmdf\1.9\wdfmemory.inc
include c:\masm32\include\wdf\kmdf\1.9\wdftimer.inc
includelib c:\masm32\lib\wxp\i386\BufferOverflowK.lib
includelib c:\masm32\lib\wxp\i386\ntoskrnl.lib
includelib c:\masm32\lib\wxp\i386\hal.lib
includelib c:\masm32\lib\wxp\i386\wmilib.lib
includelib c:\masm32\lib\wxp\i386\sehupd.lib
includelib c:\masm32\lib\wdf\kmdf\i386\1.9\wdfldr.lib
includelib c:\masm32\lib\wdf\kmdf\i386\1.9\wdfdriverentry.lib
public DriverEntry
IOCTL_START equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_ANY_ACCESS)
IOCTL_STOP equ CTL_CODE(FILE_DEVICE_UNKNOWN, 801h, METHOD_BUFFERED, FILE_ANY_ACCESS)
.const
DEV_NAME word "\","D","e","v","i","c","e","\","M","y","D","r","i","v","e","r",0
SYM_NAME word "\","D","o","s","D","e","v","i","c","e","s","\","M","y","D","r","i","v","e","r",0
MSG_START byte "IOCTL_START",0
MSG_STOP byte "IOCTL_STOP",0
.data
dwTimerCnt DWORD ?
hTimer WDFTIMER ?
.code
OnTimer proc Timer:WDFTIMER
inc dwTimerCnt
invoke DbgPrint, $CTA0("WdfTimer: %d"), dwTimerCnt
ret
OnTimer endp
IrpFileCreate proc Device:WDFDEVICE, Request:WDFREQUEST, FileObject:WDFFILEOBJECT
invoke DbgPrint, $CTA0("IrpFieCreate")
invoke WdfRequestComplete, Request, STATUS_SUCCESS
ret
IrpFileCreate endp
IrpFileClose proc FileObject:WDFFILEOBJECT
invoke DbgPrint, $CTA0("IrpFieClose")
ret
IrpFileClose endp
IrpIOCTL proc uses ebx edx Queue:WDFQUEUE, Request:WDFREQUEST, OutputBufferLength:DWORD, InputBufferLength:DWORD, IoControlCode:DWORD
local timeout:qword
local stTimeCnt:LARGE_INTEGER
.if IoControlCode == IOCTL_START
invoke DbgPrint, offset MSG_START
mov dwTimerCnt, 0
;lea ebx, timeout
;mov (dword ptr [ebx + 0]), 1000
;mov (dword ptr [ebx + 4]), 0
;invoke WDF_REL_TIMEOUT_IN_MS, timeout
;lea ebx, timeout
;mov (dword ptr [ebx + 0]), eax
;mov (dword ptr [ebx + 4]), edx
;invoke WdfTimerStart, hTimer, timeout
or stTimeCnt.HighPart, -1
mov stTimeCnt.LowPart, -10000000
invoke WdfTimerStart, hTimer, stTimeCnt.QuadPart
.elseif IoControlCode == IOCTL_STOP
invoke DbgPrint, offset MSG_STOP
invoke WdfTimerStop, hTimer, FALSE
.endif
invoke WdfRequestComplete, Request, STATUS_SUCCESS
ret
IrpIOCTL endp
AddDevice proc Driver:WDFDRIVER, pDeviceInit:PWDFDEVICE_INIT
local device:WDFDEVICE
local suDevName:UNICODE_STRING
local szSymName:UNICODE_STRING
local timer_cfg:WDF_TIMER_CONFIG
local file_cfg:WDF_FILEOBJECT_CONFIG
local ioqueue_cfg:WDF_IO_QUEUE_CONFIG
local timer_attribute:WDF_OBJECT_ATTRIBUTES
invoke RtlInitUnicodeString, addr suDevName, offset DEV_NAME
invoke RtlInitUnicodeString, addr szSymName, offset SYM_NAME
invoke WdfDeviceInitAssignName, pDeviceInit, addr suDevName
invoke WdfDeviceInitSetIoType, pDeviceInit, WdfDeviceIoBuffered
invoke WDF_FILEOBJECT_CONFIG_INIT, addr file_cfg, offset IrpFileCreate, offset IrpFileClose, NULL
invoke WdfDeviceInitSetFileObjectConfig, pDeviceInit, addr file_cfg, WDF_NO_OBJECT_ATTRIBUTES
invoke WdfDeviceCreate, addr pDeviceInit, WDF_NO_OBJECT_ATTRIBUTES, addr device
invoke WdfDeviceCreateSymbolicLink, device, addr szSymName
invoke WDF_TIMER_CONFIG_INIT_PERIODIC, addr timer_cfg, OnTimer, 1000
invoke WDF_OBJECT_ATTRIBUTES_INIT, addr timer_attribute
lea eax, timer_attribute
push device
pop (WDF_OBJECT_ATTRIBUTES ptr [eax]).ParentObject
invoke WdfTimerCreate, addr timer_cfg, addr timer_attribute, addr hTimer
invoke WDF_IO_QUEUE_CONFIG_INIT_DEFAULT_QUEUE, addr ioqueue_cfg, WdfIoQueueDispatchSequential
lea eax, ioqueue_cfg
mov (WDF_IO_QUEUE_CONFIG ptr [eax]).EvtIoDeviceControl, offset IrpIOCTL
invoke WdfIoQueueCreate, device, addr ioqueue_cfg, WDF_NO_OBJECT_ATTRIBUTES, WDF_NO_HANDLE
ret
AddDevice endp
DriverEntry proc pOurDriver:PDRIVER_OBJECT, pOurRegistry:PUNICODE_STRING
local config:WDF_DRIVER_CONFIG
invoke WDF_DRIVER_CONFIG_INIT, addr config, AddDevice
invoke WdfDriverCreate, pOurDriver, pOurRegistry, WDF_NO_OBJECT_ATTRIBUTES, addr config, WDF_NO_HANDLE
ret
DriverEntry endp
end DriverEntry
.end
AddDevice()初始化I/O Timer
IrpIOCTL()啟動或停止I/O Timer
OnTimer()僅列印訊息，其餘事情不做
app.asm
.386p
.model flat, stdcall
option casemap:none
include c:\masm32\include\windows.inc
include c:\masm32\include\masm32.inc
include c:\masm32\include\user32.inc
include c:\masm32\include\msvcrt.inc
include c:\masm32\include\kernel32.inc
include c:\masm32\include\w2k\ntddkbd.inc
include c:\masm32\Macros\Strings.mac
includelib c:\masm32\lib\user32.lib
includelib c:\masm32\lib\masm32.lib
includelib c:\masm32\lib\msvcrt.lib
includelib c:\masm32\lib\kernel32.lib
IOCTL_START equ CTL_CODE(FILE_DEVICE_UNKNOWN, 800h, METHOD_BUFFERED, FILE_ANY_ACCESS)
IOCTL_STOP equ CTL_CODE(FILE_DEVICE_UNKNOWN, 801h, METHOD_BUFFERED, FILE_ANY_ACCESS)
.const
DEV_NAME db "\\.\MyDriver",0
.data?
hFile dd ?
dwRet dd ?
.code
start:
invoke CreateFile, offset DEV_NAME, GENERIC_READ or GENERIC_WRITE, FILE_SHARE_READ, 0, OPEN_EXISTING, FILE_ATTRIBUTE_NORMAL, 0
.if eax == INVALID_HANDLE_VALUE
invoke crt_printf, $CTA0("failed to open mydriver")
invoke ExitProcess, -1
.endif
mov hFile, eax
invoke DeviceIoControl, hFile, IOCTL_START, NULL, 0, NULL, 0, offset dwRet, NULL
invoke Sleep, 3000
invoke DeviceIoControl, hFile, IOCTL_STOP, NULL, 0, NULL, 0, offset dwRet, NULL
invoke CloseHandle, hFile
invoke ExitProcess, 0
end start
結果
